IR-Packet-Buffer only returns 7 Bytes

[R-Klimkeit]

Hello,

I'm stuck with this little Visual-Studio Code-Snippet (used sdk-master\libs\include\Win64\libflirc.dll)

Imports System.Runtime.InteropServices

Module Module1
    Private Const MAX_EDGES As Integer = 256
    Private Const MAX_DESC As Integer = 100


    Sub Main()
        Dim RetVal As Integer = fl_open_device_alt(&H20A0, "flirc.tv")
        If (RetVal < 0) Then
            MsgBox("Error opening FLIRC-Device")
            End
        End If

        While (True)
            Dim packet As ir_packet = Nothing
            RetVal = fl_ir_packet_poll(packet)
            If (RetVal = 1) Then
                Console.WriteLine("Buf-Len:" & packet.len & " | Elapsed:" & packet.elapsed & " | Raw-Data:" & String.Join(" ", packet.buf).Replace(" 0", ""))
            End If
        End While
    End Sub

    <System.Runtime.InteropServices.DllImport("libflirc.dll")> Public Function fl_open_device_alt(ByVal VID As UInt16, <MarshalAs(UnmanagedType.LPWStr)> ByRef Enumerator As String) As Integer
    End Function
    <System.Runtime.InteropServices.DllImport("libflirc.dll")> Public Function fl_ir_packet_poll(ByRef packet As ir_packet) As Integer
    End Function

    <StructLayout(LayoutKind.Sequential)> Public Structure ir_prot
        Public protocol As UInt16                                                             'used to override protocol to sub protocol, NEC->APPLE_NEC
        Public scancode As UInt32                                                             '32 Bit Scancode from remote
        Public fullcode As UInt64                                                             '32 bit entire code extracted from remote (don't use this)
        Public hash As UInt32                                                                 '32 Bit Unique Hash
        Public repeat As Byte                                                                 'repeat detected=1 / no repeat=0
        Public bits As UInt32                                                                 'amount of bits collected
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=MAX_DESC)> Public desc() As Char      'Used to describe our collected signal
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=MAX_EDGES)> Public buf() As UInt16    'cleaned signal after decode
        Public len As UInt16                                                                  'length of clean buf
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=MAX_EDGES)> Public pronto() As UInt16 'pronto hex code
        Public pronto_len As UInt16                                                           'pronto length
    End Structure

    <StructLayout(LayoutKind.Sequential)> Public Structure ir_packet
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=256)> Dim buf() As UInt16
        Public len As UInt16
        Public elapsed As UInt16
    End Structure
End Module

Works like a charm, but I just realized, that the IR-Packet will only show the last 7 Raw-Bytes

Using "irtools.exe listen" from the FLIRC-Installer will show all IR-received bytes - Any idea what's wrong with my code?

[R-Klimkeit]

I desperately need help using the DLL "libflirc.dll" (from Flirc-SDK /libs/Win64/libflirc.dll) - I really consider there could be a bug in this DLL.

My Source-Code proves to be able to accept more than 7 Bytes, since there are some self-learned IR-Commands in my Logitech-Remote which are correctly received by my code - For example:
1304 1161 463 1185 2149 1159 437 1186 2123 2873 1281 1184 463 1187 461 2030 463 2029 488
This is exactly the same result as the CLI-Tool "irtools.exe listen" from the Flirc-Installation will return. 19 bytes total - No problem with this IR-Code!

But: When sending some other IR-Signals the DLL only returns the last 7 Bytes (Max-Edges set to 256) - Example as follows:
397 418 400 1295 401 1295 401
Compared to the result of "irtools.exe listen" ...
+3508 -1681 +400 -415 +399 -1297 +398 -417 +399 -414 +401 -415 +399 -416 +400 -415 +399 -416 +417 -398 +399 -416 +400 -421 +393 -416 +399 -416 +399 -1296 +400 -415 +400 -415 +400 -415 +398 -417 +401 -414 +425 -390 +399 -416 +399 -416 +400 -415 +400 -1295 +399 -416 +401 -414 +401 -414 +399 -416 +398 -416 +401 -415 +399 -415 +399 -416 +400 -1296 +400 -416 +399 -415 +399 -1296 +400 -416 +424 -391 +399 -1295 +401 -415 +424 -1270 +402 -415 +399 -415 +399 -1296 +398 -417 +397 -418 +400 -1295 +401 -1295 +401
... the DLL-Call "fl_ir_packet_poll(packet)" only returns the last 7 Bytes - Why !?!

@jdk - Can you please, please help - In fact, I am willing to get paid support (PayPal?) to solve this problem.

[R-Klimkeit]

Found the problem: I thought calling fl_ir_packet_poll(packet) would always return the whole IR-Packet ...

But: If the packet exceeds some limit (I think about 30 bytes) you have to call fl_ir_packet_poll(packet) multiple times to get the >whole< packet. The Return-Value of fl_ir_packet_poll(packet) will be "0" until all bytes have been copied to the referenced Buffer-Array. The following receiving-protocol-example shows, that fl_ir_packet_poll(packet) must be called 3 times to get the whole IR-Command:

Return-Value=0 - Buffer = 4456 4551 510 1700 481 1726 508 1698 483 614 482 564 483 590 481 589 508 566 481 1724 483 1725 508 1699 482 590 483 590 507 590
Return-Value=0 - Buffer = 4456 4551 510 1700 481 1726 508 1698 483 614 482 564 483 590 481 589 508 566 481 1724 483 1725 508 1699 482 590 483 590 507 590 455 615 457 589 483 588 509 565 481 1725 482 589 483 589 508 589 458 613 457 589 483 1725 484 1723 483 604 468 1751 456 1751 457
Return-Value=1 - Buffer = 4456 4551 510 1700 481 1726 508 1698 483 614 482 564 483 590 481 589 508 566 481 1724 483 1725 508 1699 482 590 483 590 507 590 455 615 457 589 483 588 509 565 481 1725 482 589 483 589 508 589 458 613 457 589 483 1725 484 1723 483 604 468 1751 456 1751 457 1751 481 1700 509 1699 483

Problem with my Visual-Studio-Code was: The buffer-variable was re-initialized on each fl_ir_packet_poll(packet)-Call - So I accidentally discarded the bytes, which were copied to the buffer-array while Return-Value was "0".

I will share a corrected VisualStudio-Code here after tidying up my code.

[jdk]

The Return-Value of fl_ir_packet_poll(packet) will be "0".

Yes, this is important. And it should be documented and included in all the sample code. Sorry, I don't check this area much for support. I'd be happy include your sample code once shared and I can go through/reproduce it.

[R-Klimkeit]

@jdk: Thanks for your response and for sharing this SDK - Great work!

In the end it turned out to be my own fault - Just because I differed slightly from your code by reinitializing the Packt-variable - I'm not quite sure, if addional documentation would have saved me from failing ;-)

Here is a short Visual-Studio-based CLI-Tool, for imitating "irtools.exe listen" by using your SDK - Additionally the packet gets decoded by "libir.dll". Feel free to use and redistribute as you/everyone like(s):

Imports System.Runtime.InteropServices

Module Module1
    Private Const MAX_EDGES As Integer = 256
	Private Const MAX_DESC As Integer = 100
	Private packet As ir_packet = Nothing

	Sub Main()
		Dim RetVal As Integer = fl_open_device_alt(&H20A0, "flirc.tv")
		If (RetVal < 0) Then
			Console.WriteLine("Error opening FLIRC-Device")
			End
		End If

		AddHandler Console.CancelKeyPress, AddressOf CancelKeyPress
		Console.WriteLine("Reading from Flirc-Device (press CTRL-C to stop reading):")

		While (True)
			RetVal = fl_ir_packet_poll(packet)
			If (RetVal = 1) Then 'Last packet-chunk from "fl_ir_packet_poll" received (Notice: packets of more than ~50 bytes need multiple "fl_ir_packet_poll"-calls to get the whole packet)
				Dim data As ir_prot = Nothing
				ir_decode_packet(packet, data)
				Console.WriteLine("Buf-Len:" & packet.len & " | Elapsed:" & packet.elapsed & " | ScanCode:" & data.scancode.ToString() & " | Raw-Data:" & String.Join(" ", packet.buf).Replace(" 0", ""))
				packet = Nothing 'Reset Receive-Buffer for next IR-Command
			End If
		End While
	End Sub

	Private Sub CancelKeyPress(ByVal sender As Object, ByVal args As ConsoleCancelEventArgs)
		fl_close_device()
		End
	End Sub

	<System.Runtime.InteropServices.DllImport("libflirc.dll")> Public Function fl_open_device_alt(VID As UInteger, mf As String) As Integer
    End Function
	<System.Runtime.InteropServices.DllImport("libflirc.dll")> Public Function fl_ir_packet_poll(ByRef packet As ir_packet) As Integer
	End Function
	<System.Runtime.InteropServices.DllImport("libflirc.dll")> Public Sub fl_close_device()
	End Sub
	<System.Runtime.InteropServices.DllImport("libir.dll")> Public Function ir_decode_packet(ByVal packet As ir_packet, ByRef data As ir_prot) As Integer
	End Function

	<StructLayout(LayoutKind.Sequential)> Public Structure ir_prot
		Public protocol As rc_proto                                                           'used to override protocol to sub protocol, NEC->APPLE_NEC
		Public scancode As UInt32                                                             '32 Bit Scancode from remote
		Public fullcode As UInt64                                                             '32 bit entire code extracted from remote (don't use this)
		Public hash As UInt32                                                                 '32 Bit Unique Hash
		Public repeat As Byte                                                                 'repeat detected=1 / no repeat=0
		Public bits As UInt32                                                                 'amount of bits collected
		<MarshalAs(UnmanagedType.ByValTStr, SizeConst:=MAX_DESC)> Public desc As String       'Used to describe our collected signal
		<MarshalAs(UnmanagedType.ByValArray, SizeConst:=MAX_EDGES)> Public buf() As UInt16    'cleaned signal after decode
		Public len As UInt16                                                                  'length of clean buf
		<MarshalAs(UnmanagedType.ByValArray, SizeConst:=MAX_EDGES)> Public pronto() As UInt16 'pronto hex code
		Public pronto_len As UInt16                                                           'pronto length
	End Structure

	<StructLayout(LayoutKind.Sequential)> Public Structure ir_packet
		<MarshalAs(UnmanagedType.ByValArray, SizeConst:=MAX_EDGES)> Dim buf() As UInt16
		Public len As UInt16
		Public elapsed As UInt16
	End Structure

	Public Enum rc_proto
		RC_PROTO_UNKNOWN = 0
		RC_PROTO_INVALID
		RC_PROTO_OTHER
		RC_PROTO_RC5
		RC_PROTO_RC5X_20
		RC_PROTO_RC5_SZ
		RC_PROTO_JVC
		RC_PROTO_SONY12
		RC_PROTO_SONY15
		RC_PROTO_SONY20
		RC_PROTO_NEC
		RC_PROTO_NECX
		RC_PROTO_NEC32
		RC_PROTO_NEC48
		RC_PROTO_SANYO
		RC_PROTO_MCIR2_KBD
		RC_PROTO_MCIR2_MSE
		RC_PROTO_RC6_0
		RC_PROTO_RC6_6A_20
		RC_PROTO_RC6_6A_24
		RC_PROTO_RC6_6A_32
		RC_PROTO_RC6_MCE
		RC_PROTO_SHARP
		RC_PROTO_XMP
		RC_PROTO_CEC
		RC_PROTO_IMON
		RC_PROTO_RCMM12
		RC_PROTO_RCMM24
		RC_PROTO_RCMM32
		RC_PROTO_ORTEK
		RC_PROTO_DENON
		RC_PROTO_DENONK
		RC_PROTO_FLIRC
		RC_PROTO_NOKIA12
		RC_PROTO_NOKIA24
		RC_PROTO_NOKIA32
		RC_PROTO_TDC
		RC_PROTO_AMINO
		RC_PROTO_NEC_APPLE
		RC_PROTO_NEC_REPEAT
		RC_PROTO_PANASONIC
		RC_PROTO_GAP
	End Enum
End Module

[jdk]

Nice job, thanks for the contribution. I'll take a look, integrate, and give credit.

[R-Klimkeit]

For a slightly more sophisticated version (based on this code-snippet), look here: https://forum.flirc.tv/index.php?/topic/21432-control-htpc-with-flirc/ :-)