Sample Documentation

[BobbyShoe]

Hello,

Do you have any documentation or code samples on how to receive input from the Flirc USB IR receiver? We would like to capture the IR signals from within our application.

Our application is written in C#, but we can wrap the C DLLs if needed to invoke the necessary functions.

Ideally we would like to map raw IR signals to commands in our application. However we could also possibly map the command buttons using your tool, and use the mapped keys. We would need to be able to identify the key command came from your USB IR device instead of a keyboard. Any suggestions?

Thanks,
Bobby

[t9mike]

@BobbyShoe what did you end up doing for your application? One hack seems to be to setup global keyboard capture handled in C# (such as https://github.com/jasemagee/KeyLogger) and then just map FLIRC IR to keyboard presses.

[R-Klimkeit]

The FLIRC-SDK gives you all you need to read Raw-IR-Signals with your own .NET-Application: Just add a class for PINVOKE-interoperability to the C-DLLs.

First step is to collect all needed PINVOKE-s. The header-files "libs\include\flirc.h" and "libs\include\ir.h" from the FLIRC-SDK were essential for guessing these declarations:

Imports System.Runtime.InteropServices

Public Class FLIRC_InterOp
    Private Const MAX_EDGES As Integer = 256
    Private Const MAX_DESC As Integer = 100

    <System.Runtime.InteropServices.DllImport("libflirc.dll")> Public Shared Function fl_open_device_alt(ByVal VID As IntPtr, <MarshalAs(UnmanagedType.LPWStr)> ByVal Identifier As String) As Integer
    End Function
    <System.Runtime.InteropServices.DllImport("libflirc.dll")> Public Shared Sub fl_close_device()
    End Sub
    <System.Runtime.InteropServices.DllImport("libflirc.dll")> Public Shared Function fl_ir_packet_poll(ByRef packet As ir_packet) As Integer
    End Function
    <System.Runtime.InteropServices.DllImport("libflirc.dll")> Public Shared Function fl_lib_version() As IntPtr
    End Function
    <System.Runtime.InteropServices.DllImport("libir.dll")> Public Shared Function ir_decode_packet(ByVal packet As ir_packet, ByRef data As ir_prot) As Integer
    End Function
    <System.Runtime.InteropServices.DllImport("libir.dll")> Public Shared Function ir_lib_version() As IntPtr
    End Function

    <StructLayout(LayoutKind.Sequential)> Public Structure ir_prot
        Public protocol As UInt16                                                             'used to override protocol to sub protocol, NEC->APPLE_NEC
        Public scancode As UInt32                                                             '32 Bit Scancode from remote
        Public fullcode As UInt64                                                             '32 bit entire code extracted from remote (don't use this)
        Public hash As UInt32                                                                 '32 Bit Unique Hash
        Public repeat As Byte                                                                 'repeat detected=1 / no repeat=0
        Public bits As UInt32                                                                 'amount of bits collected
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=MAX_DESC)> Public desc() As Char      'Used to describe our collected signal
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=MAX_EDGES)> Public buf() As UInt16    'cleaned signal after decode
        Public len As UInt16                                                                  'length of clean buf
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=MAX_EDGES)> Public pronto() As UInt16 'pronto hex code
        Public pronto_len As UInt16                                                           'pronto length
    End Structure

    <StructLayout(LayoutKind.Sequential)> Public Structure ir_packet
        <MarshalAs(UnmanagedType.ByValArray, SizeConst:=256)> Dim buf() As UInt16
        Public len As UInt16
        Public elapsed As UInt16
    End Structure
End Class

From this point on, it's quite simple to imitate the Raw-Read-function as introduced by "irtools.exe listen" ... A closer look at the SDK-resource "ir\main.c" was helpful to get an idea of how to interact with FLIRC:

Imports System.ComponentModel
Public Class Form1
    Private Sub btnStart_Click(sender As Object, e As EventArgs) Handles btnStart.Click
        Dim RetVal As Integer = FLIRC_InterOp.fl_open_device_alt(&H20A0, "flirc.tv")
        If (RetVal < 0) Then
            MsgBox("Error opening FLIRC-Device")
            Exit Sub
        End If

        btnStart.Enabled = False
        lblFLversion.Text = "FL-Version: " & System.Runtime.InteropServices.Marshal.PtrToStringAnsi(FLIRC_InterOp.fl_lib_version())
        lblIRversion.Text = "IR-Version: " & System.Runtime.InteropServices.Marshal.PtrToStringAnsi(FLIRC_InterOp.ir_lib_version())
        Timer1.Enabled = True
    End Sub

    Private Sub Form_FLIRC_ReadRaw_Closing(sender As Object, e As CancelEventArgs) Handles Me.Closing
        Timer1.Enabled = False
        System.Threading.Thread.Sleep(2 * Timer1.Interval)
        FLIRC_InterOp.fl_close_device()
    End Sub

    Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
        Try
            Dim packet As FLIRC_InterOp.ir_packet = Nothing
            Dim RetVal As Integer = FLIRC_InterOp.fl_ir_packet_poll(packet)
            If (RetVal = 1) Then 'IR-Frame received
                Dim data As FLIRC_InterOp.ir_prot = Nothing
                FLIRC_InterOp.ir_decode_packet(packet, data)
                Dim RowNum As Integer = dgvLogging.Rows.Add()
                dgvLogging.Rows(RowNum).SetValues(Now.ToString("HH:mm:ss.ffff"),
                                                  data.protocol.ToString(),
                                                  data.scancode.ToString(),
                                                  data.fullcode.ToString(),
                                                  data.hash.ToString(),
                                                  data.repeat.ToString(),
                                                  data.bits.ToString(),
                                                  String.Join("", data.desc).Replace(vbNullChar, ""),
                                                  String.Join(" ", data.buf).Replace(" 0", ""),
                                                  data.len,
                                                  String.Join(" ", data.pronto).Replace(" 0", ""),
                                                  data.pronto_len)
                If (dgvLogging.Rows.Count > 10) Then dgvLogging.Rows.RemoveAt(0)
            End If
        Catch ex As Exception
        End Try
    End Sub
End Class

As you can see: Most lines handle outputting the received IR-data to a DataGridView ... Only a few lines are about the FLIRC-communication, since the SDK's DLL-s do a quite good job ;-)

I think this VB-Code should be easily converted to C# if necessary. Hope this helps.

[R-Klimkeit]

Attention: I noticed an issue with my .NET-Code as mentioned here #21
If you find a solution for this problem: Please let me know ;-)

[R-Klimkeit]

Be sure to use the corrected source-code from here #21 (comment)