C6 Feedback

[gmint]

I noticed that the status of the ESP32-C6 is currently listed as "untested." With IDF-5.3.0 I can confirm that I have it working with one stepper motor and the MCPWM_PCNT driver. I've used it with RMT as well and it also works. It does seem that I lose some step precision when moving backwards on occasion and I have not tried to resolve this with the suggestions given elsewhere regarding the connection of the driver as I am currently working around this issue. If there is anything else that I can help with as far as testing this configuration, I am willing to give it a try!

[gin66]

Thanks for sharing, that it is working on your side.

For rmt driver on espidf5.3 is as expected, But the mcpwm/pcnt driver should actually not be available. Wonder what here is going on. Could you please check ?

For the step loosing issue: you could attach a pulse counter and double check, that pulses are not lost from the electronics/SW side.

[gmint]

My apologies for taking so long to reply to this. I did finally get this implemented and I am seeing some discrepancies between the pulse counter and the internal position. For example, this is after a very short run in just one direction:

Pulse Count: 1707
Motor Position: 1464

It's really just all over the place when I test. Is there anything in particular I should be looking for?

[gin66]

Thanks for the feedback. It would be great, if you can share the code.

[gmint]

This is the operative code. I'm checking the position in a different function (via the web interface) so that isn't reflected here, but I can post that too if it's needed.

#include "StepperControl.h"
#include "Config.h"

#ifdef USE_STEPPER
#include <FastAccelStepper.h>

#define ENABLE_PIN 15
#define STEP_PIN   7
#define DIR_PIN    6

FastAccelStepperEngine engine;
FastAccelStepper *fastStepper = nullptr;

const int maxStepperPosition = 12500;
const int minSpeed = 100;
const int maxSpeed = 4000;
const int minAcceleration = 100;
const int maxAcceleration = 3000;

int previousSpeed = -1;
int previousAcceleration = -1;
int lastDMXPosition = -1;
int lastDMXSpeed = -1;
int lastDMXAccel = -1;
int pulseCount = 0;
int motorPosition = 0;

void initStepper() {
    engine.init();
    fastStepper = engine.stepperConnectToPin(STEP_PIN);
    if (!fastStepper) {
        Serial.println("Failed to init FastAccelStepper with MCPWM_PCNT driver");
        return;
    }

    fastStepper->setDirectionPin(DIR_PIN);
    fastStepper->setEnablePin(ENABLE_PIN);
    fastStepper->enableOutputs();
    fastStepper->setSpeedInHz(maxSpeed);
    fastStepper->setAcceleration(maxAcceleration);
    fastStepper->applySpeedAcceleration();
    fastStepper->setCurrentPosition(0);
    fastStepper->attachToPulseCounter(); // Attach the built-in pulse counter

    Serial.println("Stepper initialized.");
}

void readPulseCounter() {
    pulseCount = fastStepper->readPulseCounter(); // Store value in global variable
    motorPosition = fastStepper->getCurrentPosition();
    return;
}

void handleStepperDMX(const uint8_t* data, uint16_t universe, int startDMXAddress, int startUniverse, uint16_t dmxLength) {
    if (universe != startUniverse) return;

    static bool motorEnabled = false;
    static unsigned long lastCheckTime = 0;

    if (startDMXAddress < 1 || (startDMXAddress + 2) > dmxLength) {
        Serial.println("Invalid DMX address or insufficient data for stepper.");
        return;
    }

    int positionValue = (data[startDMXAddress - 1] << 8) | data[startDMXAddress];
    if (positionValue == 0) {
        if (fastStepper->getCurrentPosition() != 0) {
            fastStepper->moveTo(0);
        }

        if (millis() - lastCheckTime > 10) {
            lastCheckTime = millis();
            if (fastStepper->getCurrentPosition() == 0 && motorEnabled) {
                fastStepper->disableOutputs();
                motorEnabled = false;
            }
        }
        return;
    } else {
        if (!motorEnabled) {
            fastStepper->enableOutputs();
            motorEnabled = true;
        }
    }

    int targetPosition = map(positionValue, 0, 65535, 0, maxStepperPosition);
    int speedValue = data[startDMXAddress + 1];
    int targetSpeed = map(speedValue, 0, 255, minSpeed, maxSpeed);
    int accelValue = data[startDMXAddress + 2];
    int targetAccel = map(accelValue, 0, 255, minAcceleration, maxAcceleration);

    if (!fastStepper) {
        Serial.println("FastStepper object is not valid.");
        return;
    }

    if (targetSpeed != previousSpeed) {
        fastStepper->setSpeedInHz(targetSpeed);
        previousSpeed = targetSpeed;
    }

    if (targetAccel != previousAcceleration) {
        fastStepper->setAcceleration(targetAccel);
        previousAcceleration = targetAccel;
    }

    fastStepper->moveTo(targetPosition);
}


void clearPulseCounter() {
    fastStepper->clearPulseCounter();
}

bool pulseCounterAttached() {
    return fastStepper->pulseCounterAttached();
}
#endif

[gmint]

I should have probably included a little about the application here. I have a DMX controlled stepper motor that acts as a lifter for various objects. Eventually I will have a better homing mechanism but right now I essentially have the position reset itself by disconnecting the driver when it is at the bottom position (basically gravity does the work).

[gin66]

Thanks. Nothing obvious for any root cause. Do you think, you could get the esp32 test suite to work ?
here.

This requires mainly, that the StepperDemo is flashed in the device with the needed step/dir/enable assignments in the code. Actually a nice tool to test the stepper. You can even attach a free pulse counter and compare it while stepper is running.

Besides, I have put an esp32c6 device in my AliExpress shopping cart for approx. 6€. Once the shopping cart is eligible for free shipping, I will get it and can test myself. Just not sure, when this will happen.

[AllanMar]

Is there any update on this? ESP32-C6 (working on ESP32-C3) not working for me, not getting any steps. Waiting to do some more debugging but wanted to confirm if there was any more testing with ESP32c6?

PLATFORM: Espressif 32 (55.3.35) > Seeed Studio XIAO ESP32C6
HARDWARE: ESP32C6 160MHz, 320KB RAM, 4MB Flash
DEBUG: Current (cmsis-dap) External (cmsis-dap, esp-bridge, esp-builtin, esp-prog, iot-bus-jtag, jlink, minimodule, olimex-arm-usb-ocd, olimex-arm-usb-ocd-h, olimex-arm-usb-tiny-h, olimex-jtag-tiny, tumpa)
PACKAGES:

• contrib-piohome @ 3.4.4
• framework-arduinoespressif32 @ 3.3.5
• framework-arduinoespressif32-libs @ 5.5.0+sha.9bb7aa84fe
• tool-esptoolpy @ 5.1.0
• tool-mklittlefs @ 3.2.0
• toolchain-riscv32-esp @ 14.2.0+20251107