GH-47787: [C++][FlightRPC] ODBC msi Windows installer

.github/workflows/cpp_extra.yml

@@ -346,6 +346,7 @@ jobs:
       ARROW_BUILD_TYPE: release
       ARROW_DEPENDENCY_SOURCE: VCPKG
       ARROW_FLIGHT_SQL_ODBC: ON
+      ARROW_FLIGHT_SQL_ODBC_INSTALLER: ON
       ARROW_SIMD_LEVEL: AVX2
       CMAKE_CXX_STANDARD: "17"
       CMAKE_GENERATOR: Ninja
@@ -434,7 +435,24 @@ jobs:
       # GH-48269 TODO: Enable Flight & Flight SQL testing in MSVC CI
       # GH-48547 TODO: enable ODBC tests after GH-48270 and GH-48269 are resolved.
 
-      # GH-47787 TODO: Build ODBC installer
+      - name: Install WiX Toolset
+        shell: pwsh
+        run: |
+          Invoke-WebRequest -Uri https://github.com/wixtoolset/wix/releases/download/v6.0.0/wix-cli-x64.msi -OutFile wix-cli-x64.msi
+          Start-Process -FilePath wix-cli-x64.msi -ArgumentList '/quiet', 'Include_freethreaded=1' -Wait
+          echo "C:\Program Files\WiX Toolset v6.0\bin\" | Out-File -FilePath $env:GITHUB_PATH -Encoding utf8 -Append
+      - name: Build MSI ODBC installer
+        shell: pwsh
+        run: |
+          # Verify WiX version
+          wix --version
+          cd "${{ github.workspace }}\build\cpp"
+          cpack
+      - name: Upload the artifacts to the job
+        uses: actions/upload-artifact@v6
+        with:
+          name: flight-sql-odbc-msi-installer
+          path: ${{ github.workspace }}\build\cpp\Apache Arrow Flight SQL ODBC-1.0.0-win64.msi
 
   report-extra-cpp:
     if: github.event_name == 'schedule' && always()

.gitignore

@@ -107,3 +107,6 @@ java/.mvn/.develocity/
 # rat
 filtered_rat.txt
 rat.txt
+
+# rc
+*.rc

ci/scripts/cpp_build.sh

@@ -65,6 +65,7 @@ if [ "${ARROW_ENABLE_THREADING:-ON}" = "OFF" ]; then
   ARROW_FLIGHT=OFF
   ARROW_FLIGHT_SQL=OFF
   ARROW_FLIGHT_SQL_ODBC=OFF
+  ARROW_FLIGHT_SQL_ODBC_INSTALLER=OFF
   ARROW_GCS=OFF
   ARROW_JEMALLOC=OFF
   ARROW_MIMALLOC=OFF
@@ -213,6 +214,7 @@ else
     -DARROW_FLIGHT=${ARROW_FLIGHT:-OFF} \
     -DARROW_FLIGHT_SQL=${ARROW_FLIGHT_SQL:-OFF} \
     -DARROW_FLIGHT_SQL_ODBC=${ARROW_FLIGHT_SQL_ODBC:-OFF} \
+    -DARROW_FLIGHT_SQL_ODBC_INSTALLER=${ARROW_FLIGHT_SQL_ODBC_INSTALLER:-OFF} \
     -DARROW_FUZZING=${ARROW_FUZZING:-OFF} \
     -DARROW_GANDIVA_PC_CXX_FLAGS=${ARROW_GANDIVA_PC_CXX_FLAGS:-} \
     -DARROW_GANDIVA=${ARROW_GANDIVA:-OFF} \

cpp/CMakeLists.txt

@@ -720,9 +720,13 @@ endif()
 
 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/../LICENSE.txt
               ${CMAKE_CURRENT_SOURCE_DIR}/../NOTICE.txt
-              ${CMAKE_CURRENT_SOURCE_DIR}/README.md DESTINATION "${ARROW_DOC_DIR}")
+              ${CMAKE_CURRENT_SOURCE_DIR}/README.md
+        DESTINATION "${ARROW_DOC_DIR}"
+        COMPONENT arrow_doc)
 
-install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/gdb_arrow.py DESTINATION "${ARROW_GDB_DIR}")
+install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/gdb_arrow.py
+        DESTINATION "${ARROW_GDB_DIR}"
+        COMPONENT arrow_gdb)
 
 #
 # Validate and print out Arrow configuration options

cpp/CMakePresets.json

@@ -180,6 +180,7 @@
         "ARROW_BUILD_EXAMPLES": "ON",
         "ARROW_BUILD_UTILITIES": "ON",
         "ARROW_FLIGHT_SQL_ODBC": "ON",
+        "ARROW_FLIGHT_SQL_ODBC_INSTALLER": "ON",
         "ARROW_TENSORFLOW": "ON",
         "PARQUET_BUILD_EXAMPLES": "ON",
         "PARQUET_BUILD_EXECUTABLES": "ON"

cpp/cmake_modules/BuildUtils.cmake

@@ -178,10 +178,12 @@ function(arrow_install_cmake_package PACKAGE_NAME EXPORT_NAME)
   write_basic_package_version_file("${BUILT_CONFIG_VERSION_CMAKE}"
                                    COMPATIBILITY SameMajorVersion)
   install(FILES "${BUILT_CONFIG_CMAKE}" "${BUILT_CONFIG_VERSION_CMAKE}"
-          DESTINATION "${ARROW_CMAKE_DIR}/${PACKAGE_NAME}")
+          DESTINATION "${ARROW_CMAKE_DIR}/${PACKAGE_NAME}"
+          COMPONENT ${EXPORT_NAME}_config_cmake_files)
   set(TARGETS_CMAKE "${PACKAGE_NAME}Targets.cmake")
   install(EXPORT ${EXPORT_NAME}
           DESTINATION "${ARROW_CMAKE_DIR}/${PACKAGE_NAME}"
+          COMPONENT ${EXPORT_NAME}_target_export
           NAMESPACE "${PACKAGE_NAME}::"
           FILE "${TARGETS_CMAKE}")
 endfunction()
@@ -403,8 +405,11 @@ function(ADD_ARROW_LIB LIB_NAME)
     install(TARGETS ${LIB_NAME}_shared ${INSTALL_IS_OPTIONAL}
             EXPORT ${LIB_NAME}_targets
             ARCHIVE DESTINATION ${INSTALL_ARCHIVE_DIR}
+                    COMPONENT ${LIB_NAME}_shared_archive
             LIBRARY DESTINATION ${INSTALL_LIBRARY_DIR}
+                    COMPONENT ${LIB_NAME}_shared_library
             RUNTIME DESTINATION ${INSTALL_RUNTIME_DIR}
+                    COMPONENT ${LIB_NAME}_shared_runtime
             INCLUDES
             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
   endif()
@@ -471,8 +476,11 @@ function(ADD_ARROW_LIB LIB_NAME)
     install(TARGETS ${LIB_NAME}_static ${INSTALL_IS_OPTIONAL}
             EXPORT ${LIB_NAME}_targets
             ARCHIVE DESTINATION ${INSTALL_ARCHIVE_DIR}
+                    COMPONENT ${LIB_NAME}_static_library
             LIBRARY DESTINATION ${INSTALL_LIBRARY_DIR}
+                    COMPONENT ${LIB_NAME}_static_library
             RUNTIME DESTINATION ${INSTALL_RUNTIME_DIR}
+                    COMPONENT ${LIB_NAME}_static_library
             INCLUDES
             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
   endif()
@@ -934,7 +942,9 @@ function(ARROW_INSTALL_ALL_HEADERS PATH)
     endif()
     list(APPEND PUBLIC_HEADERS ${HEADER})
   endforeach()
-  install(FILES ${PUBLIC_HEADERS} DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${PATH}")
+  install(FILES ${PUBLIC_HEADERS}
+          DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${PATH}"
+          COMPONENT ${HEADER}_header)
 endfunction()
 
 function(ARROW_ADD_PKG_CONFIG MODULE)
@@ -944,7 +954,8 @@ function(ARROW_ADD_PKG_CONFIG MODULE)
        OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/${MODULE}.pc"
        INPUT "${CMAKE_CURRENT_BINARY_DIR}/${MODULE}.pc.generate.in")
   install(FILES "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/${MODULE}.pc"
-          DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig/")
+          DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig/"
+          COMPONENT ${MODULE}_pkg_config)
 endfunction()
 
 # Implementations of lisp "car" and "cdr" functions

cpp/cmake_modules/DefineOptions.cmake

@@ -347,6 +347,12 @@ takes precedence over ccache if a storage backend is configured" ON)
                 ARROW_FLIGHT_SQL
                 ARROW_COMPUTE)
 
+  define_option(ARROW_FLIGHT_SQL_ODBC_INSTALLER
+                "Build the Arrow Flight SQL ODBC installer"
+                OFF
+                DEPENDS
+                ARROW_FLIGHT_SQL_ODBC)
+
   define_option(ARROW_GANDIVA
                 "Build the Gandiva libraries"
                 OFF

cpp/cmake_modules/ThirdpartyToolchain.cmake

@@ -236,7 +236,8 @@ function(provide_cmake_module MODULE_NAME ARROW_CMAKE_PACKAGE_NAME)
     message(STATUS "Providing CMake module for ${MODULE_NAME} as part of ${ARROW_CMAKE_PACKAGE_NAME} CMake package"
     )
     install(FILES "${module}"
-            DESTINATION "${ARROW_CMAKE_DIR}/${ARROW_CMAKE_PACKAGE_NAME}")
+            DESTINATION "${ARROW_CMAKE_DIR}/${ARROW_CMAKE_PACKAGE_NAME}"
+            COMPONENT ${MODULE_NAME}_module)
   endif()
 endfunction()
 
@@ -2442,20 +2443,22 @@ function(build_gtest)
   endforeach()
   install(DIRECTORY "${googletest_SOURCE_DIR}/googlemock/include/"
                     "${googletest_SOURCE_DIR}/googletest/include/"
-          DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+          DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
+          COMPONENT gtest_dir)
   add_library(arrow::GTest::gtest_headers INTERFACE IMPORTED)
   target_include_directories(arrow::GTest::gtest_headers
                              INTERFACE "${googletest_SOURCE_DIR}/googlemock/include/"
                                        "${googletest_SOURCE_DIR}/googletest/include/")
   install(TARGETS gmock gmock_main gtest gtest_main
           EXPORT arrow_testing_targets
-          RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
-          ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
-          LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}")
+          RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}" COMPONENT gtest_runtime
+          ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}" COMPONENT gtest_archive
+          LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}" COMPONENT gtest_library)
   if(MSVC)
     install(FILES $<TARGET_PDB_FILE:gmock> $<TARGET_PDB_FILE:gmock_main>
                   $<TARGET_PDB_FILE:gtest> $<TARGET_PDB_FILE:gtest_main>
             DESTINATION "${CMAKE_INSTALL_BINDIR}"
+            COMPONENT gtest_pdb
             OPTIONAL)
   endif()
   add_library(arrow::GTest::gmock ALIAS gmock)

cpp/src/arrow/CMakeLists.txt

@@ -349,7 +349,8 @@ string(REPLACE "${CMAKE_BINARY_DIR}" "<CMAKE_BINARY_DIR>" REDACTED_CXX_FLAGS
 configure_file("util/config.h.cmake" "util/config.h" ESCAPE_QUOTES)
 configure_file("util/config_internal.h.cmake" "util/config_internal.h" ESCAPE_QUOTES)
 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/util/config.h"
-        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/arrow/util")
+        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/arrow/util"
+        COMPONENT arrow_config)
 
 set(ARROW_SRCS
     builder.cc
@@ -1051,7 +1052,8 @@ if(ARROW_BUILD_BUNDLED_DEPENDENCIES)
   get_target_property(arrow_bundled_dependencies_path arrow_bundled_dependencies
                       IMPORTED_LOCATION)
   install(FILES ${arrow_bundled_dependencies_path} ${INSTALL_IS_OPTIONAL}
-          DESTINATION ${CMAKE_INSTALL_LIBDIR})
+          DESTINATION ${CMAKE_INSTALL_LIBDIR}
+          COMPONENT arrow_bundled_dependencies)
   string(PREPEND ARROW_PC_LIBS_PRIVATE " -larrow_bundled_dependencies")
   list(INSERT ARROW_STATIC_INSTALL_INTERFACE_LIBS 0 "Arrow::arrow_bundled_dependencies")
 endif()
@@ -1168,6 +1170,7 @@ if(ARROW_BUILD_SHARED AND NOT WIN32)
   if(ARROW_GDB_AUTO_LOAD_LIBARROW_GDB_INSTALL)
     install(FILES "${CMAKE_CURRENT_BINARY_DIR}/libarrow_gdb.py"
             DESTINATION "${ARROW_GDB_AUTO_LOAD_LIBARROW_GDB_DIR}"
+            COMPONENT arrow_gdb
             RENAME "$<TARGET_FILE_NAME:arrow_shared>-gdb.py")
   endif()
 endif()
@@ -1231,11 +1234,13 @@ arrow_install_all_headers("arrow")
 
 config_summary_cmake_setters("${CMAKE_CURRENT_BINARY_DIR}/ArrowOptions.cmake")
 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/ArrowOptions.cmake
-        DESTINATION "${ARROW_CMAKE_DIR}/Arrow")
+        DESTINATION "${ARROW_CMAKE_DIR}/Arrow"
+        COMPONENT arrow_options_cmake)
 
 # For backward compatibility for find_package(arrow)
 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/arrow-config.cmake
-        DESTINATION "${ARROW_CMAKE_DIR}/Arrow")
+        DESTINATION "${ARROW_CMAKE_DIR}/Arrow"
+        COMPONENT arrow_config_cmake)
 
 #
 # Unit tests

cpp/src/arrow/flight/sql/odbc/CMakeLists.txt

@@ -19,8 +19,6 @@
 # GH-44792: Arrow will switch to C++ 20
 set(CMAKE_CXX_STANDARD 20)
 
-add_custom_target(arrow_flight_sql_odbc)
-
 if(WIN32)
   if(MSVC_VERSION GREATER_EQUAL 1900)
     set(ODBCINST legacy_stdio_definitions odbccp32 shlwapi)
@@ -38,10 +36,28 @@ add_subdirectory(tests)
 
 arrow_install_all_headers("arrow/flight/sql/odbc")
 
+# ODBC Release information
+set(ODBC_PACKAGE_VERSION_MAJOR "1")
+set(ODBC_PACKAGE_VERSION_MINOR "0")
+set(ODBC_PACKAGE_VERSION_PATCH "0")
+set(ODBC_PACKAGE_NAME "Apache Arrow Flight SQL ODBC")
+set(ODBC_PACKAGE_VENDOR "Apache Arrow")
+
 set(ARROW_FLIGHT_SQL_ODBC_SRCS entry_points.cc odbc_api.cc)
 
 if(WIN32)
-  list(APPEND ARROW_FLIGHT_SQL_ODBC_SRCS odbc.def)
+  set(VER_FILEVERSION
+      "${ODBC_PACKAGE_VERSION_MAJOR},${ODBC_PACKAGE_VERSION_MINOR},${ODBC_PACKAGE_VERSION_PATCH},0"
+  )
+  set(VER_FILEVERSION_STR
+      ${ODBC_PACKAGE_VERSION_MAJOR}.${ODBC_PACKAGE_VERSION_MINOR}.${ODBC_PACKAGE_VERSION_PATCH}
+  )
+  set(VER_COMPANYNAME_STR ${ODBC_PACKAGE_VENDOR})
+  set(VER_PRODUCTNAME_STR ${ODBC_PACKAGE_NAME})
+
+  configure_file("install/windows/versioninfo.rc.in" "install/versioninfo.rc" @ONLY)
+
+  list(APPEND ARROW_FLIGHT_SQL_ODBC_SRCS odbc.def install/versioninfo.rc)
 endif()
 
 add_arrow_lib(arrow_flight_sql_odbc
@@ -75,3 +91,71 @@ add_arrow_lib(arrow_flight_sql_odbc
 foreach(LIB_TARGET ${ARROW_FLIGHT_SQL_ODBC_LIBRARIES})
   target_compile_definitions(${LIB_TARGET} PRIVATE ARROW_FLIGHT_SQL_ODBC_EXPORTING)
 endforeach()
+
+# Construct ODBC Windows installer. Only Release installer is supported
+if(ARROW_FLIGHT_SQL_ODBC_INSTALLER)
+
+  include(InstallRequiredSystemLibraries)
+
+  set(CPACK_RESOURCE_FILE_LICENSE
+      "${CMAKE_CURRENT_SOURCE_DIR}/../../../../../../LICENSE.txt")
+  # Tentative version 1.0.0
+  set(CPACK_PACKAGE_VERSION_MAJOR ${ODBC_PACKAGE_VERSION_MAJOR})
+  set(CPACK_PACKAGE_VERSION_MINOR ${ODBC_PACKAGE_VERSION_MINOR})
+  set(CPACK_PACKAGE_VERSION_PATCH ${ODBC_PACKAGE_VERSION_PATCH})
+
+  set(CPACK_PACKAGE_NAME ${ODBC_PACKAGE_NAME})
+  set(CPACK_PACKAGE_VENDOR ${ODBC_PACKAGE_VENDOR})
+  set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Apache Arrow Flight SQL ODBC Driver")
+  set(CPACK_PACKAGE_CONTACT "#GH-47787 TODO arrow maintainers")
+
+  # GH-47876 TODO: set up `arrow_flight_sql_odbc` component for macOS Installer
+  # GH-47877 TODO: set up `arrow_flight_sql_odbc` component for Linux Installer
+  if(WIN32)
+    # Install ODBC and its Arrow dependencies
+    install(TARGETS arrow_shared
+                    arrow_compute_shared
+                    arrow_flight_shared
+                    arrow_flight_sql_shared
+                    arrow_flight_sql_odbc_shared
+                    RUNTIME_DEPENDENCIES
+                    PRE_EXCLUDE_REGEXES
+                    "api-ms-.*"
+                    "ext-ms-.*"
+                    POST_EXCLUDE_REGEXES
+                    ".*system32/.*\\.dll"
+            RUNTIME DESTINATION bin COMPONENT arrow_flight_sql_odbc)
+
+    set(CPACK_WIX_EXTRA_SOURCES
+        "${CMAKE_CURRENT_SOURCE_DIR}/install/windows/arrow-flight-sql-odbc.wxs")
+    set(CPACK_WIX_PATCH_FILE
+        "${CMAKE_CURRENT_SOURCE_DIR}/install/windows/arrow-flight-sql-odbc-patch.xml")
+
+    set(CPACK_WIX_UI_BANNER
+        "${CMAKE_CURRENT_SOURCE_DIR}/install/windows/arrow-wix-banner.bmp")
+  endif()
+
+  get_cmake_property(CPACK_COMPONENTS_ALL COMPONENTS)
+  set(CPACK_COMPONENTS_ALL Unspecified)
+  list(APPEND CPACK_COMPONENTS_ALL "arrow_flight_sql_odbc")
+
+  if(WIN32)
+    # WiX msi installer on Windows
+    # CPack is compatible with WiX V.5 and V.6
+    set(CPACK_GENERATOR "WIX")
+    set(CPACK_WIX_VERSION 4)
+
+    # Upgrade GUID is required to be unchanged for ODBC installer to upgrade
+    set(CPACK_WIX_UPGRADE_GUID "DBF27A18-F8BF-423F-9E3A-957414D52C4B")
+    set(CPACK_WIX_PRODUCT_GUID "279D087B-93B5-4DC3-BA69-BCF485022A26")
+  endif()
+  # GH-47876 TODO: create macOS Installer using cpack
+  # GH-47877 TODO: create Linux Installer using cpack
+
+  # Load CPack after all CPACK* variables are set
+  include(CPack)
+  cpack_add_component(arrow_flight_sql_odbc
+                      DISPLAY_NAME "ODBC library"
+                      DESCRIPTION "ODBC library bin, required to install"
+                      REQUIRED)
+endif()